# Maintainer: Alexander Epaneshnikov <alex19ep@archlinux.org>
# Contributor: Sean Anderson <seanga2@gmail.com>

pkgname=perl-syntax-keyword-try
pkgver=0.30
pkgrel=3
pkgdesc="a try/catch/finally syntax for perl"
arch=(x86_64)
url="https://metacpan.org/release/Syntax-Keyword-Try"
license=('GPL' 'PerlArtistic')
depends=(perl perl-xs-parse-keyword)
makedepends=(perl-module-build perl-file-sharedir)
options=(!emptydirs purge)
source=("https://cpan.metacpan.org/authors/id/P/PE/PEVANS/Syntax-Keyword-Try-$pkgver.tar.gz")
sha512sums=('dbabccdcf973d4ba0bf32e0499898b16260b8b8dede2abd7bc33a4cdfdd1da0816cd5f02d55f75eae2cea2381af2fd7fbcf5758ff5cdba067fe3ba7f535c7d20')

build() {
	cd "Syntax-Keyword-Try-$pkgver"
	unset PERL5LIB PERL_MM_OPT PERL_MB_OPT PERL_LOCAL_LIB_ROOT
	export PERL_MM_USE_DEFAULT=1 MODULEBUILDRC=/dev/null
	/usr/bin/perl Build.PL
	./Build
}

check() {
	cd "Syntax-Keyword-Try-$pkgver"
	unset PERL5LIB PERL_MM_OPT PERL_MB_OPT PERL_LOCAL_LIB_ROOT
	export PERL_MM_USE_DEFAULT=1
	./Build test
}

package() {
	cd "Syntax-Keyword-Try-$pkgver"
	unset PERL5LIB PERL_MM_OPT PERL_MB_OPT PERL_LOCAL_LIB_ROOT
	./Build install --installdirs=vendor --destdir="$pkgdir"
}
